package{
import Box2D.Collision.Shapes.b2CircleShape;
import Box2D.Collision.Shapes.b2PolygonShape;
import Box2D.Collision.Shapes.b2Shape;
import Box2D.Collision.b2AABB;
import Box2D.Common.Math.b2Vec2;
import Box2D.Dynamics.Joints.b2DistanceJoint;
import Box2D.Dynamics.Joints.b2DistanceJointDef;
import Box2D.Dynamics.Joints.b2MouseJoint;
import Box2D.Dynamics.Joints.b2MouseJointDef;
import Box2D.Dynamics.Joints.b2RevoluteJoint;
import Box2D.Dynamics.Joints.b2RevoluteJointDef;
import Box2D.Dynamics.b2Body;
import Box2D.Dynamics.b2BodyDef;
import Box2D.Dynamics.b2DebugDraw;
import Box2D.Dynamics.b2Fixture;
import Box2D.Dynamics.b2FixtureDef;
import Box2D.Dynamics.b2World;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
[SWF(width=”800″,height=”600″,frameRate=”32″,backgroundColor=”0x000000″)]
public class RevoluteJoint_Sling extends Sprite{
private var world:b2World;
private var body:b2Body;
private var bodyDef:b2BodyDef = new b2BodyDef();
private var fixtureDef:b2FixtureDef = new b2FixtureDef();
private var timeStep:Number;
private var iterations:uint;
private var pixelsPerMeter:Number = 30;
private var mouseJoint:b2MouseJoint;
private var mousePVec:b2Vec2 = new b2Vec2();
private var distanceJoint:b2DistanceJoint;
public function RevoluteJoint_Sling(){
createWorld();
makeDebugDraw();
createWall();
createBoxes();
createJoint();
addEventListener(Event.ENTER_FRAME,onEnterframe);
stage.addEventListener(MouseEvent.MOUSE_DOWN,onMouseDown);
stage.addEventListener(MouseEvent.MOUSE_UP,onMouseUp);
}
private function createWorld():void{
var gravity:b2Vec2 = new b2Vec2(0.0,9.8);
var doSleep:Boolean = true;
world = new b2World(gravity,doSleep);
world.SetWarmStarting(true);
timeStep = 1.0/30.0;
iterations = 10;
}
private function makeDebugDraw():void{
var debugDraw:b2DebugDraw = new b2DebugDraw();
var debugSprite:Sprite = new Sprite();
addChild(debugSprite);
debugDraw.SetSprite(debugSprite);
debugDraw.SetDrawScale(30.0);
debugDraw.SetFillAlpha(0.5);
debugDraw.SetLineThickness(1.0);
debugDraw.SetFlags(b2DebugDraw.e_shapeBit | b2DebugDraw.e_jointBit);
world.SetDebugDraw(debugDraw);
}
private function createWall():void{
bodyDef.position.Set(400/pixelsPerMeter,585/pixelsPerMeter);
var box:b2PolygonShape = new b2PolygonShape();
box.SetAsBox(400/pixelsPerMeter,15/pixelsPerMeter);
fixtureDef.shape = box;
fixtureDef.density = 0;
fixtureDef.friction = 0.4;
fixtureDef.restitution = 0.1;
body = world.CreateBody(bodyDef);
body.CreateFixture(fixtureDef);
}
private function createBoxes():void{
for(var i:int=0;i<10;i++){
bodyDef.type = b2Body.b2_dynamicBody;
bodyDef.position.Set(580/pixelsPerMeter,(540-i*40)/pixelsPerMeter);
var box:b2PolygonShape = new b2PolygonShape();
box.SetAsBox(20/pixelsPerMeter,20/pixelsPerMeter);
fixtureDef.shape = box;
fixtureDef.density = 0.5;
fixtureDef.friction = 0.3;
body = world.CreateBody(bodyDef);
body.CreateFixture(fixtureDef);
}
}
private function createJoint():void{
bodyDef = new b2BodyDef();
bodyDef.position.Set(210/pixelsPerMeter,225/pixelsPerMeter);
var circleShape:b2CircleShape = new b2CircleShape(9/pixelsPerMeter);
var pivot:b2Body = world.CreateBody(bodyDef);
pivot.CreateFixture2(circleShape);
bodyDef = new b2BodyDef();
bodyDef.type = b2Body.b2_dynamicBody;
bodyDef.position.Set(210/pixelsPerMeter,225/pixelsPerMeter);
var boxShape:b2PolygonShape = new b2PolygonShape();
boxShape.SetAsBox(60/pixelsPerMeter,9/pixelsPerMeter);
fixtureDef.shape = boxShape;
fixtureDef.density = 0.01;
fixtureDef.friction = 1;
fixtureDef.restitution = 0.1;
var box:b2Body = world.CreateBody(bodyDef);
box.CreateFixture(fixtureDef);
var revoluteJointDef:b2RevoluteJointDef = new b2RevoluteJointDef();
revoluteJointDef.Initialize(pivot,box,pivot.GetWorldCenter());
revoluteJointDef.enableMotor = true;
revoluteJointDef.motorSpeed = 10;
revoluteJointDef.maxMotorTorque = 1000;
var revoluteJoint:b2RevoluteJoint = world.CreateJoint(revoluteJointDef) as b2RevoluteJoint;
bodyDef.position.Set(110/pixelsPerMeter,225/pixelsPerMeter);
boxShape.SetAsBox(9/pixelsPerMeter,9/pixelsPerMeter);
fixtureDef.shape = boxShape;
fixtureDef.density = 1.0;
fixtureDef.friction = 0.4;
fixtureDef.restitution = 0.1;
var bullet:b2Body = world.CreateBody(bodyDef);
bullet.CreateFixture(fixtureDef);
var distanceJointDef:b2DistanceJointDef = new b2DistanceJointDef();
distanceJointDef.Initialize(bullet,box,
new b2Vec2(110/pixelsPerMeter,225/pixelsPerMeter),
new b2Vec2(150/pixelsPerMeter,225/pixelsPerMeter));
distanceJointDef.collideConnected = true;
distanceJoint = world.CreateJoint(distanceJointDef) as b2DistanceJoint;
}
private function onMouseDown(e:MouseEvent):void{
var body:b2Body = getBodyAtMouse();
if(body){
var mouseJointDef:b2MouseJointDef = new b2MouseJointDef();
mouseJointDef.bodyA = world.GetGroundBody();
mouseJointDef.bodyB = body;
mouseJointDef.target.Set(mouseX/pixelsPerMeter,mouseY/pixelsPerMeter);
mouseJointDef.maxForce = 30000;
mouseJoint = world.CreateJoint(mouseJointDef) as b2MouseJoint;
}
}
private function onMouseUp(e:MouseEvent):void{
if(distanceJoint){
world.DestroyJoint(distanceJoint);
distanceJoint = null;
}
if(mouseJoint){
world.DestroyJoint(mouseJoint);
mouseJoint = null;
}
}
private function getBodyAtMouse(includeStatic:Boolean = false):b2Body{
var mouseXWorldPhys:Number = mouseX/pixelsPerMeter;
var mouseYWorldPhys:Number = mouseY/pixelsPerMeter;
mousePVec.Set(mouseXWorldPhys,mouseYWorldPhys);
var aabb:b2AABB = new b2AABB();
aabb.lowerBound.Set(mouseXWorldPhys-0.001,mouseYWorldPhys-0.001);
aabb.upperBound.Set(mouseXWorldPhys+0.001,mouseYWorldPhys+0.001);
var body:b2Body = null;
var fixture:b2Fixture;
function GetBodyCallBack(fixture:b2Fixture):Boolean{
var shape:b2Shape = fixture.GetShape();
if(fixture.GetBody().GetType() != b2Body.b2_staticBody || includeStatic){
var inside:Boolean = shape.TestPoint(fixture.GetBody().GetTransform(),mousePVec);
if(inside){
body = fixture.GetBody();
return false;
}
}
return true;
}
world.QueryAABB(GetBodyCallBack,aabb);
return body;
}
private function onEnterframe(e:Event):void{
world.Step(timeStep,iterations,iterations);
world.ClearForces();
world.DrawDebugData();
if(mouseJoint){
var xpos:Number = mouseX/pixelsPerMeter;
var ypos:Number = mouseY/pixelsPerMeter;
var v2:b2Vec2 = new b2Vec2(xpos,ypos);
mouseJoint.SetTarget(v2);
}
}
}
}
[/code]
转载请注明：陈童的博客 » box2d旋转关节之投掷
