package{
import Box2D.Collision.Shapes.b2PolygonShape;
import Box2D.Collision.Shapes.b2Shape;
import Box2D.Collision.b2AABB;
import Box2D.Common.Math.b2Vec2;
import Box2D.Dynamics.Joints.b2MouseJoint;
import Box2D.Dynamics.Joints.b2MouseJointDef;
import Box2D.Dynamics.Joints.b2RevoluteJointDef;
import Box2D.Dynamics.b2Body;
import Box2D.Dynamics.b2BodyDef;
import Box2D.Dynamics.b2DebugDraw;
import Box2D.Dynamics.b2Fixture;
import Box2D.Dynamics.b2FixtureDef;
import Box2D.Dynamics.b2World;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
[SWF(width=”800″,height=”600″,frameRate=”32″,backgroundColor=”0x000000″)]
public class RevoluteJoint_Rope extends Sprite{
private var world:b2World;
private var timeStep:Number;
private var iterations:uint;
private var pixelsPerMeter:Number = 30;
private var mouseJoint:b2MouseJoint;
private var mousePVec:b2Vec2 = new b2Vec2();
public function RevoluteJoint_Rope(){
createWorld();
makeDebugDraw();
createRope();
addEventListener(Event.ENTER_FRAME,onEnterframe);
stage.addEventListener(MouseEvent.MOUSE_DOWN,onMouseDown);
stage.addEventListener(MouseEvent.MOUSE_UP,onMouseUp);
}
private function createWorld():void{
var gravity:b2Vec2 = new b2Vec2(0.0,9.8);
var doSleep:Boolean = true;
world = new b2World(gravity,doSleep);
world.SetWarmStarting(true);
timeStep = 1.0/30.0;
iterations = 10;
}
private function makeDebugDraw():void{
var debugDraw:b2DebugDraw = new b2DebugDraw();
var debugSprite:Sprite = new Sprite();
addChild(debugSprite);
debugDraw.SetSprite(debugSprite);
debugDraw.SetDrawScale(30.0);
debugDraw.SetFillAlpha(0.5);
debugDraw.SetLineThickness(1.0);
debugDraw.SetFlags(b2DebugDraw.e_shapeBit);
world.SetDebugDraw(debugDraw);
}
private function createRope():void{
//天棚
var bodyDef:b2BodyDef = new b2BodyDef();
bodyDef.position.Set(400/pixelsPerMeter,0);
var body:b2Body = world.CreateBody(bodyDef);
var box:b2PolygonShape = new b2PolygonShape();
box.SetAsBox(60/pixelsPerMeter,15/pixelsPerMeter);
body.CreateFixture2(box);
var link:b2Body = body;
var fixtureDef:b2FixtureDef = new b2FixtureDef();
var jointDef:b2RevoluteJointDef = new b2RevoluteJointDef();
for(var i:int=0;i<10;i++){
// 10段绳索
bodyDef = new b2BodyDef();
bodyDef.type = b2Body.b2_dynamicBody;
bodyDef.position.Set(400/pixelsPerMeter,(i*30+30)/pixelsPerMeter);trace(i*30+15);
box = new b2PolygonShape();
box.SetAsBox(3/pixelsPerMeter,15/pixelsPerMeter);
fixtureDef.shape = box;
fixtureDef.density = 100;
fixtureDef.friction = 0.5;
fixtureDef.restitution = 0.2;
body = world.CreateBody(bodyDef);
body.CreateFixture(fixtureDef);
// Joint
jointDef.Initialize(link,body,new b2Vec2(400/pixelsPerMeter,(i*30+15)/pixelsPerMeter));
world.CreateJoint(jointDef);
link = body;
}
// 绳索悬挂物
bodyDef = new b2BodyDef();
bodyDef.type = b2Body.b2_dynamicBody;
bodyDef.position.Set(400/pixelsPerMeter,330/pixelsPerMeter);
box = new b2PolygonShape();
box.SetAsBox(15/pixelsPerMeter,15/pixelsPerMeter);
fixtureDef = new b2FixtureDef();
fixtureDef.shape = box;
fixtureDef.density = 2;
fixtureDef.friction = 0.5;
fixtureDef.restitution = 0.2;
body = world.CreateBody(bodyDef);
body.CreateFixture(fixtureDef);
jointDef.Initialize(link,body,new b2Vec2(400/pixelsPerMeter,315/pixelsPerMeter));
world.CreateJoint(jointDef);
}
private function onMouseDown(e:MouseEvent):void{
var body:b2Body = getBodyAtMouse();
if(body){
var mouseJointDef:b2MouseJointDef = new b2MouseJointDef();
mouseJointDef.bodyA = world.GetGroundBody();
mouseJointDef.bodyB = body;
mouseJointDef.target.Set(mouseX/pixelsPerMeter,mouseY/pixelsPerMeter);
mouseJointDef.maxForce = 30000;
mouseJoint = world.CreateJoint(mouseJointDef) as b2MouseJoint;
}
}
private function onMouseUp(e:MouseEvent):void{
if(mouseJoint){
world.DestroyJoint(mouseJoint);
mouseJoint = null;
}
}
private function getBodyAtMouse(includeStatic:Boolean = false):b2Body{
var mouseXWorldPhys:Number = mouseX/pixelsPerMeter;
var mouseYWorldPhys:Number = mouseY/pixelsPerMeter;
mousePVec.Set(mouseXWorldPhys,mouseYWorldPhys);
var aabb:b2AABB = new b2AABB();
aabb.lowerBound.Set(mouseXWorldPhys-0.001,mouseYWorldPhys-0.001);
aabb.upperBound.Set(mouseXWorldPhys+0.001,mouseYWorldPhys+0.001);
var body:b2Body = null;
var fixture:b2Fixture;
function GetBodyCallBack(fixture:b2Fixture):Boolean{
var shape:b2Shape = fixture.GetShape();
if(fixture.GetBody().GetType() != b2Body.b2_staticBody || includeStatic){
var inside:Boolean = shape.TestPoint(fixture.GetBody().GetTransform(),mousePVec);
if(inside){
body = fixture.GetBody();
return false;
}
}
return true;
}
world.QueryAABB(GetBodyCallBack,aabb);
return body;
}
private function onEnterframe(e:Event):void{
world.Step(timeStep,iterations,iterations);
world.ClearForces();
world.DrawDebugData();
if(mouseJoint){
var xpos:Number = mouseX/pixelsPerMeter;
var ypos:Number = mouseY/pixelsPerMeter;
var v2:b2Vec2 = new b2Vec2(xpos,ypos);
mouseJoint.SetTarget(v2);
}
}
}
}
[/code]
转载请注明：陈童的博客 » box2d旋转关节之绳索
